Program Gauss_D
! DUBLA Precizie
!
! Program principal pt. ELIM
! Cu matricile: "A(n,n)" si "b(n,nb)"
! A. b: generate; citite din fisierul de intrare; citite din din fisier de date.
!
! Selectia fisierului de intrare - prin fereastra de dialog standard.
!
! Fisier de date (intrare):
! 1) Titlu
! 2) n, nb, kodAb
! 3) [A]
! 4) [b]
! 5) kod_Inv, kod_PrintA, kod_Print
! 6) check_text
!
! Semnificatia:
! Titlu: text <= 80 caractere
!
! n, nb: nr. de ecuatii; nr. de termeni liberi.
! kodAb: Cod de intare a matricilor "A" si "b":
!		kodAb <=0: matrici A,b, generate - de subrutina GenAB;
!		kodAb =1: matrici citite din fisierul de intrare
!
!		kodAb =2: matrice A generala, si b, citite dintr-un fisier de date;
!		kodAb >=3:matrice A simetrica, si b, citite dintr-un fisier de date
!				Prima linie in fisierul specificat e o linie text (max. 80 caractere).
!
! A: Matricea coeficientilor n x n
!    Se scrie asa cum e data - pe linii si coloane
!    Pentru kod_Ab >=3: se introduce triunghiul superior (pe linii).
!
! b: Termenii liberi
!    Se scriu pe linii: "nb" linii a "n" termeni liberi.
!
! kod_Inv: Cod_inversare_coeficienti
!	      kod_Inv: #0: a(i,j) -> 1./a(i,j)
! kodPrintA: cod tiparire matrici
!	kod_PrintA: #0: Se tiparesc matricile A si b
! kod_PrintP: cod_Tiparire
!	kod_PrintP: #0: Se tiparesc permutarile si pivotii.
!
! Check_text: text <= 20 caractere. Primul caracter e semnificativ:
!	'C', 'c', 'P', 'p', 'F', 'f': se face proba "Ax-b" (pentru fiecare termen liber).
!   C,c, P, p: se tipareste diferenta maxima in modul "Ax-b"
!   F,f: se tiparesc diferentele "Ax-b".
!
!
implicit real(8) (a-h,o-z)

real(8), allocatable :: A(:,:), B(:,:)
character(260) fname, fname2, titlu*80

real(8) prag /1E-14/    !8/	! Curent /1E-6/; Pentru test:/1E-7/; Prag pentru Pivot ~0.
integer width

real(8), allocatable :: a0(:,:), b0(:,:)

character(20) check_text
logical do_check, full_check 

character(80) dummy
character(40) text

real(8) max_dif
integer status


! Selecteza fisierul de intrare:
call GetFile(fname, status, 'Select Input File'C)

open(1, file =fname, status ='old', form ='formatted')

! citeste:
read(1,'(a)') TITLU

read(1,*) n, nb, kodAb

allocate (A(n,n), B(n, nb))

! citeste/genereaza A si b:
if (kodAb <=0) then
call GenAB(n, nb, a, b)

elseif (kodAb ==1) then
	do i =1,n
	read(1,*) (a(i,j), j= 1,n)
	enddo

	do j =1,nb
	read(1,*) (b(i,j), i= 1,n)
	enddo

else	! kodAb >=2
	call GetFile(fname2, status, 'Select Ab-Matrices File'C)
	open(2, file =fname2, status ='old', form ='formatted')

	read(2,*) dummy
		sim_if: if(kodAb ==2) then
! A:
		do i =1,n
		read(2,*) (a(i,j), j= 1,n)
		enddo

		else	! matrice simetrica: triunghiul superior
		do i =1,n
		read(2,*) ( a(i,j), j=i,n )
		enddo

		! completeaza simetric:
		do i =1,n
		do j =1,i
		a(i,j) =a(j,i)
		enddo
		enddo

		endif sim_if

! b:
	do j =1,nb
	read(2,*) (b(i,j), i= 1,n)
	enddo

	close(2)

endif

! citeste coduri:
read(1,*) kod_Inv, kod_PrintA, kod_PrintP

! citeste "Proba"
read(1,*) check_text

full_check =check_text(1:1) =='F' .or. check_text(1:1) =='f'

do_check =check_text(1:1) =='C' .or. check_text(1:1) =='c' &
	 .or. check_text(1:1) =='P' .or. check_text(1:1) =='p' &
	 .or. full_check

if(kod_Inv /=0) then
!do i=1,n
!do j=1,n
!a(i,j) =1./a(i,j)
!enddo
!enddo
A =1./A
endif

! 
if(kod_PrintA /=0) then
! write A:
write(1,'(/,a)') 'Matricea A'
	do i =1,n
	write(1,*) (a(i,j), j= 1,n)
	enddo

! write b:
write(1,'(/,a)') 'Termenii liberi b'

	do i =1,n
	write(1,*) (b(i,j), j= 1,nb)
	enddo

endif

! Pt. Proba:
if(do_check) then
allocate(a0(n,n), b0(n,nb))
a0 =a; b0 =b;
endif

	call ELIM(n, nb, A, B, prag, kod, kod_PrintP)

if(kod <0) then
write(1, '(/, a, 1pE8.2,a, /,a)') '* Pivot <', prag,' !',&
'* Sistemul nu se poate rezolva.'

write(*, '(/, a, 1pE8.2,a, /,a)') '* Pivot <', prag,' !',&
'* Sistemul nu se poate rezolva.'

goto 500
endif

iwnb =width(nb)

nb_do: do k =1,nb
write(1, '(/, a, I<iwnb>)') ' * Solutia pentru termenii liberi nr. ', k

	n_do: do i=1,n
	iwi =width(i)
	write(1, '(a, I<iwi>, a, G15.7)') ' x(', i, ') = ', B(i,k)
	enddo n_do
enddo nb_do

! Proba: Solutia
Check_if: IF(do_check) THEN
write(1, '(//,a)') ' * Proba'

if(full_check) then
write(1, '(/,a)') ' Diferente (A*x-b)'

else
write(1, '(/,a)') ' Diferenta (A*x-b), maxima in modul'
endif


b_do: DO kb =1,nb
iwk =width(kb)

if(nb >1) then
write(1, '(/, a, I<iwk>, a)') ' Solutia nr. ', kb, ':'
endif

!x =b(1:n,kb)

max_dif =0.
imax =1

do i =1,n
sum =0.
	do k=1,n
	sum =sum +a0(i,k)*b(k,kb)		!x(k)
	enddo

dif =sum -b0(i,kb)
if(full_check) write(1,*) i, dif

!max_dif =max(abs(dif), max_dif)
adif =abs(dif)
if(adif >max_dif)then
max_dif =adif
dif_max =dif
imax =i
endif

enddo

if(full_check) then
write(1, '(/, a, \)') ' Diferenta (A*x-b), maxima in modul:'
endif

	if(imax>0) then
	iwm =width(imax)+1
	write(1, '(1pg15.7, a, i<iwm>)') dif_max, '; ecuatia', imax

	else
	write(1,*) dif_max
	endif

ENDDO b_do

ENDIF Check_if


500 deallocate(A, b)
if(allocated(a0)) deallocate(a0)
if(allocated(b0)) deallocate(b0)

END Program Gauss_D

